home *** CD-ROM | disk | FTP | other *** search
/ L' Effet Pommier 3 / L'Effet Pommier - Volume 03.iso / Graphismes / 3D / POV-Ray 3.0B5a PPC / POV-Ray 3.0B5a / POVSCN.Scenes / POVSCN / LEVEL1 / GLASDISH.POV < prev    next >
Text File  |  1995-11-08  |  2KB  |  90 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File by Dan Farmer
  3.  
  4. #version 3.0
  5. global_settings { assumed_gamma 2.2 }
  6.  
  7. #include "colors.inc"
  8. #include "textures.inc"
  9. #include "glass.inc"
  10. #include "woods.inc"
  11.  
  12. camera {
  13.    location  <0.0, 1.5, -2>
  14.    direction <0, 0,   1>
  15.    up        <0, 1,   0>
  16.    right   <4/3, 0,   0>
  17.    look_at   <0, 0,   0>
  18. }
  19.  
  20. // Light source (backlit)
  21. light_source {<0, 30, 10> color White
  22.     spotlight
  23.     point_at <0,0,0>
  24.     radius 8
  25.     falloff 20
  26. }
  27.  
  28. // A "sky sphere" to reflect in the glass
  29. sky_sphere {
  30.     pigment {
  31.         gradient y
  32.         color_map {
  33.             [0.0 Black ]
  34.             [1.0 Gray50 ]
  35.         }
  36.     }
  37. }
  38.  
  39. plane { y, -1
  40.    texture {
  41.        pigment {
  42.           P_WoodGrain4A
  43.           color_map { M_Wood4A }
  44. //          scale 0.5
  45.           translate <-1.5, 0.3, 1>
  46.           warp
  47.           {
  48.             black_hole <0.5, 0, 0.5>, 1.25
  49.             falloff 2
  50.             strength 2
  51.             inverse
  52.             turbulence <0.15, 0.15, 0.15>
  53.           }
  54.           warp
  55.           {
  56.             black_hole <-1.5, 0, 0.3>, 1.5
  57.             falloff 2
  58.             strength 2
  59.             inverse
  60.             turbulence <0.75, 0.75, 0.75>
  61.           }
  62.           warp
  63.           {
  64.             black_hole <1, 0, -0.5>, 1.95
  65.             falloff 1
  66.             strength 2
  67.             inverse
  68.             turbulence <0.05, 0.05, 0.05>
  69.           }
  70.         }
  71.     scale <1, 1, 2>
  72.     }
  73. }
  74.  
  75. // Crystal dish
  76. intersection {
  77.    sphere {<0, 0, 0>, 1}
  78.    sphere {<0, 0.25, 0>, 0.75 inverse}
  79.    plane  {y, 0.75 }
  80.    texture {T_Glass3
  81.       finish{
  82.          reflection 0.25
  83.          caustics 2.0
  84.          fade_distance 2
  85.          fade_power 2
  86.      }
  87.    }
  88. }
  89.  
  90.